#!/usr/local/bin/perl -w
use strict;

(my $basename = $0) =~ s!.*/!!;

sub Usage() {
  return <<USAGE;
Usage:
  $basename [-f from] filename ...
For each foo.tex letter file supplied at the command line, creates a
foo.env.tex envelope, assuming it can find the '\\begin{letter}'
and other necessary constructs (if it can't, it skips the file).
USAGE
}

sub Make_envelope {
  my ($From_name, $From_address, $To) = @_;

  for ($From_name, $From_address, $To) {
    s/^\s+//mg;
    s/$/ \\\\/ unless /\\\\$/; # No m, only care about the very last line here.
  }

  $To =~ s/^/\\>/mg;

  return <<LATEX;
\\documentclass[12pt]{article}
%\\usepackage{color}

\\setlength{\\topmargin}{-.75in}
\\setlength{\\headheight}{0in}
\\setlength{\\headsep}{0in}
\\setlength{\\topskip}{0in}
\\setlength{\\oddsidemargin}{-.75in}
\\setlength{\\parindent}{0in}
\\pagestyle{empty}

\\begin{document}

$From_name
$From_address
\\vspace{.75in}

\\begin{tabbing}
\\hspace*{4in}\\= \\kill
$To
\\end{tabbing}
%\\normalcolor
\\end{document}
LATEX
}

sub Extract_latex_env {
  my ($Latex, $Environment) = @_;
  my $Env_contents;

  if ($Latex =~ /\\$Environment\{(.*\})/s) {
    my $Search = $1;
    my $Count  = 1;
    my $Found  = 0;
    while ($Search =~ /\G(.*?(?<!\\)(?:\\\\)*([{}]))/gs) {
      $2 eq '{' ? $Count++ : $Count--;
      $Env_contents .= $1;
      $Found = 1, last if ($Count == 0);
    }
    if ($Found) {
      chop   $Env_contents; # Remove that last closing brace.
      return $Env_contents;
    } else {
      return;
    }
  } else {
    return;
  }
}


if (@ARGV==0 || $ARGV[0] eq '--help') {
  warn Usage;
  exit;
}

my %From; # Overrides signature field in letter.
my %Envelope;

my @OLDARGV = @ARGV;
      @ARGV =    ();
while (@OLDARGV) {
  my $Arg = shift(@OLDARGV);
  my $From;
  if ($Arg eq '-f') {
    $From = shift(@OLDARGV);
    $Arg  = shift(@OLDARGV);
    $From{$Arg} = $From;
  }
  $Envelope{$Arg} = $Arg;
  if ($Envelope{$Arg} =~ /\.tex$/) {
    $Envelope{$Arg} =~ s/\.tex$/.env.tex/;
  } else {
    $Envelope{$Arg} .= '.env.tex';
  }

  push @ARGV, $Arg;
}

# If there's nothing left, someone messed up.
if (@ARGV == 0) {
  warn Usage;
  exit(1);
}


foreach my $ARG (@ARGV) {
  open  LETTER,	"$ARG" or
    warn ("$basename: Could not open $ARG for read, skipping: $!"), next;
  my $Letter;

  {
    local $/;
    $Letter = <LETTER>;
  }

  close LETTER 		or
    die  "$basename: Could not close $ARG, $!";

  my ($From_name, $From_address, $To);

  if (defined($From{$ARG})) {
    $From_name = $From{$ARG};
  } elsif ($From_name = Extract_latex_env($Letter, 'signature')) {
    ;
  } else {
    warn ("$basename: No sender name defined (or mismatched braces) for
	$ARG, skipping.\n"), next;
  }

  unless ($From_address = Extract_latex_env($Letter, 'address')) {
    warn ("$basename: No sender address defined (or mismatched braces) for
	$ARG, skipping.\n"), next;
  }

  unless ($To = Extract_latex_env($Letter, 'begin{letter}')) {
    warn ("$basename: No recipient information defined (or mismatched braces)
	for $ARG, skipping.\n"), next;
  }

  open  ENV, ">$Envelope{$ARG}" or
    warn ("$basename: Could not open $Envelope{$ARG} for write, skipping: $!"),
    next;

  print ENV Make_envelope($From_name, $From_address, $To);

  close ENV or
    die "$basename: Could not close $Envelope{$ARG}, $!";
}