#!/usr/bin/perl -w
use strict;

(my $basename = $0) =~ s!.*/!!;

sub Extract_latex_env {
  my ($Latex, $Environment) = @_;
  my $Env_contents;

  if ($Latex =~ /(\\$Environment(?:\[.*?\])*\{)(.*\})/s) {
    $Env_contents = $1;
    my $Search = $2;
    my $Count  = 1;
    my $Found  = 0;
    while ($Search =~ /\G(.*?(?<!\\)(?:\\\\)*([{}]))/gs) {
      $2 eq '{' ? $Count++ : $Count--;
      $Env_contents .= $1;
      $Found = 1, last if ($Count == 0);
    }
    if ($Found) {
#      chop   $Env_contents; # Remove that last closing brace.
      return $Env_contents;
    } else {
      return;
    }
  } else {
    return;
  }
}


my %subfigure_refs;
{
  my $figure_counter=0;
  local *ALL_FIGS;
  sub convert_figure {
    my $figure         = $_[0];
    my $preamble       = $_[1];
    my $subfigure_refs = $_[2];

    my $stretch_factor = 1.44; # Factor inserted in \resizebox commands for
                               # creating an individual (converted) figure.
    unless ($figure_counter) {
      open ALL_FIGS, '>all_figs.tex' or
	die "$basename: could not open all_figs.tex for write, $!";
      print ALL_FIGS <<EOFIG;
$preamble

\\pagestyle{empty}

\\newcommand{\\figstretch}{$stretch_factor}
\\renewcommand*{\\thesubfigure}{{\\large(\\alph{subfigure})}}
\\renewcommand{\\caption}[1]{}

\\begin{document}
EOFIG
    }
    $figure_counter++;
    my $subfigure_counter='a';
    my $figure_filename_format = 'fig%d';
    my $figure_fileroot = sprintf($figure_filename_format,$figure_counter);
    my $output_figure = $figure;
    $output_figure =~ s/(\\resizebox{)(\\)/$1\\figstretch$2/g;
# WRONG!!! DANGER WILL ROBINSON!!!
#    $output_figure =~ s/(\\resizebox{.*?}{)(\\)

    open FIG, ">$figure_fileroot.tex" or
      die "$basename: could not open $figure_fileroot.tex for write, $!";

    print FIG <<EOFIG;
$preamble

\\pagestyle{empty}

\\newcommand{\\figstretch}{$stretch_factor}
\\renewcommand*{\\thesubfigure}{{\\large(\\alph{subfigure})}}
\\renewcommand{\\caption}[1]{}

\\begin{document}
$output_figure
\\end{document}
EOFIG

    close FIG or
      die "$basename: could not close $figure_fileroot.tex, $!";

    system('latex', $figure_fileroot) == 0 or
      die "$basename: latex compilation of $figure_fileroot.tex failed, $?";

    system('dvips', '-t', 'letter', '-o', "$figure_fileroot.ps",
	   $figure_fileroot) == 0 or
      die "$basename: dvips of $figure_fileroot.dvi failed, $?";

    system('ps2epsi', "$figure_fileroot.ps", "$figure_fileroot.eps") == 0 or
      die "$basename: ps2epsi of $figure_fileroot.ps failed, $?";

    while (my $subfigure = Extract_latex_env($figure, 'subfigure')) {
      my $label;
      if ($label = Extract_latex_env($subfigure, 'label')) {
	$label =~ s/^\\label{(.*)}$/$1/s;
	${$subfigure_refs}{$label} =
	  "$figure_counter($subfigure_counter)";
      }
      $subfigure_counter++;
      $figure =~ s/\Q$subfigure\E//;
    }

    while (my $resizebox = Extract_latex_env($figure, 'resizebox')) {
      $figure =~ s/\Q$resizebox\E//;
    }

    while (my $includegraphics =
	   Extract_latex_env($figure, 'includegraphics')) {
      $figure =~ s/\Q$includegraphics\E//;
    }

# TERRIBLE kludge hear.  Assumes \figsize has been defined in $preamble,
# and that it is the same for all figures.  Need a way to allow each figure
# to inform the output about what size it should be.
    $figure =~ s/(?=\\caption)/\\resizebox{\\figstretch\\figsize}{!}{
\\includegraphics{$figure_fileroot.eps}}\n/;

    return $figure;
  }
}

sub Usage() {
  return <<USAGE;
Usage:
  $basename input_tex_file [output_tex_file]
Takes a .tex file input_tex_file prepared using the IEEEtrans class,
and generates a .tex file plus figures suitable for submission: standalone
figures with simple names (fig1.eps, fig2.eps etc.) are generated, the
.bbl file is inserted directly into the output, a list of figure captions
is appended to the document, etc.
USAGE
}

if (@ARGV==0 || $ARGV[0] eq '--help') {
  warn Usage;
  exit;
}

my $input_tex_file = shift;
my $output_tex_file;
if (@ARGV) {
  $output_tex_file = $ARGV[0];
} else {
  ($output_tex_file = $input_tex_file) =~ s/(?=(?:\.tex)?$)/.ieee/;
}


my $stretch_factor = 2.0625; # Factor inserted in \resizebox commands for
                        # including converted figures.

open TEX, "$input_tex_file" or
  die "$basename: could not open $input_tex_file for read, $!";

my $tex;

while (<TEX>) {
  next if (/^%/);
  s/^(.*?(?<!\\)(?:\\\\)*%).*?$/$1/; # Remove comments.
  s/(?<!\\)(\\\\)(.)/$1\n$2/g; # Forces newlines after tex's linebreak.
                               # (That way I can just check for \ref,
                               # without worrying that someone typed \\ref.
  $tex .= $_;
}

close TEX or
  die "$basename: could not close $input_tex_file, $!";

(my $bbl_file = $input_tex_file) =~ s/(?:\.tex)?$/.bbl/;

open BBL, "$bbl_file" or
  die "$basename: could not open $bbl_file for read, $!";

my $bbl;

{
  local $/;
  $bbl = <BBL>;
}

close BBL or
  die "$basename: could not close $bbl_file, $!";

my $preamble;

if ($tex =~ /^(.*)(?=\\begin{document})/s) {
  $preamble = $1;
} else {
  die "$basename: no \\begin{document} found in $input_tex_file, aborting.\n";
}

$tex =~ s/(?=\\begin{document})/\\newcommand{\\figstretch}{$stretch_factor}\n/;

$tex =~ s/(\\begin({figure\*?}).*?\\end\2)/
  convert_figure($1,$preamble,\%subfigure_refs)/seg;

$tex =~ s/(\\ref{(.*?)})/exists($subfigure_refs{$2}) ?
  $subfigure_refs{$2} : $1/eg;

$tex =~ s/\\bibliography{.*?}/$bbl/;

$tex =~ s/(?=\\end{document})/\n\\clearpage\n\\listoffigures\n/;

open TEX, ">$output_tex_file" or
  die "$basename: could not open $output_tex_file for read, $!";

print TEX $tex;

close TEX or
  die "$basename: could not close $output_tex_file, $!";