#!/usr/bin/perl -w -n

BEGIN {
  undef $/;
  use strict;
  use vars qw($basename %Entries);

  ($basename = $0) =~ s!.*/!!;

  sub usage () {
    return <<USAGE;
Usage:
  $basename file.bib [...]
Takes a set of bibtex files, reads in all the entries, and then warns
if any of the entries have the same labels.
USAGE
  }

  if (@ARGV == 0 || $ARGV[0] eq '--help') {
    warn usage;
    exit(0);
  }
}


while (/^(\@\w+{(.*?),)/mg) {
  my $Entry_text = $1;
  my $Label      = $2;
  my $Count      =  1;
  while (/\G(.*?(?<!\\)(?:\\\\)*([{}]))/gs) {
    $2 eq '{' ? $Count++ : $Count--;
    $Entry_text .= $1;
    last if ($Count == 0);
  }

  my $Entry = {File => $ARGV,
	       Text => $Entry_text,
	      };

  if (exists($Entries{$Label})) {
    if (ref($Entries{$Label}) eq 'ARRAY') {
      push @{$Entries{$Label}}, $Entry;
    } else {
      $Entries{$Label} = [$Entries{$Label}, $Entry];
    }
  } else {
    $Entries{$Label} = $Entry;
  }
}


END {#Show duplicates here.
  foreach my $Label (sort keys %Entries) {
    if (ref($Entries{$Label}) eq 'ARRAY') {
      print "Duplicate entries for LABEL => {$Label}:\n";
      foreach my $Entry (@{$Entries{$Label}}) {
	print "\tfrom FILE => $Entry->{File}, Entry is:\n";
	print "$Entry->{Text}\n";
      }
      print "=======\n\n";
    }
  }
}